RDP Sensitive Settings Changed

/*
 * Copyright 2025 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

rule rdp_sensitive_settings_changed {

  meta:
    author = "Samir Bousseaden, David ANDRE, Roberto Rodriguez @Cyb3rWard0g, Nasreddine Bencherchali"
    description = "Detects tampering of RDP Terminal Service/Server sensitive settings. Such as allowing unauthorized users access to a system via the 'fAllowUnsolicited' or enabling RDP via 'fDenyTSConnections'...etc"
    reference = "https://github.com/SigmaHQ/sigma/blob/master/rules/windows/registry/registry_set/registry_set_terminal_server_tampering.yml"
    license = "https://github.com/SigmaHQ/Detection-Rule-License/blob/main/LICENSE.Detection.Rules.md"
    rule_name = "RDP Sensitive Settings Changed"
    rule_id = "mr_4c75375c-7ebf-4f9f-9b30-7aaab63dba8d"
    sigma_uuid = "3f6b7b62-61aa-45db-96bd-9c31b36b653c"
    sigma_status = "test"
    tactic = "TA0005"
    //tactic = "TA0003"
    technique = "T1112"
    type = "Detection"
    data_source = "Windows Registry"
    platform = "Windows"
    severity = "High"
    priority = "High"
    false_positives = "Some of the keys mentioned here could be modified by an administrator while setting group policy"

  events:
    $reg.metadata.event_type = "REGISTRY_MODIFICATION"
    (
        (
            (
                strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\control\\terminal server\\") or
                strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\windows nt\\terminal services\\")
            ) and
            re.regex($reg.target.registry.registry_key, `\\Shadow$`) nocase and
            (
                $reg.target.registry.registry_value_data = "DWORD (0x00000001)" nocase or
                $reg.target.registry.registry_value_data = "DWORD (0x00000002)" nocase or
                $reg.target.registry.registry_value_data = "DWORD (0x00000003)" nocase or
                $reg.target.registry.registry_value_data = "DWORD (0x00000004)" nocase
            )
        )
        or
        (
            (
                strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\control\\terminal server\\") or
                strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\windows nt\\terminal services\\")
            ) and
            (
                re.regex($reg.target.registry.registry_key, `\\DisableRemoteDesktopAntiAlias$`) nocase or
                re.regex($reg.target.registry.registry_key, `\\DisableSecuritySettings$`) nocase or
                re.regex($reg.target.registry.registry_key, `\\fAllowUnsolicited$`) nocase or
                re.regex($reg.target.registry.registry_key, `\\fAllowUnsolicitedFullControl$`) nocase
            ) and
            $reg.target.registry.registry_value_data = "DWORD (0x00000001)" nocase
        )
        or
        (
            strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\control\\terminal server\\initialprogram") or
            strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\control\\terminal server\\winstations\\rdp-tcp\\initialprogram") or
            strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\services\\termservice\\parameters\\servicedll") or
            strings.contains(strings.to_lower($reg.target.registry.registry_key), "\\windows nt\\terminal services\\initialprogram")
        )
    )
    $reg.principal.hostname = $hostname

  match:
    $hostname over 5m

  outcome:
    //example usage of specifying test user and hostname to adjust risk score
    $risk_score = max(if($reg.principal.user.userid = "user" and $reg.principal.hostname = "hostname", 0, 15))
    $principal_hostname = array_distinct($reg.principal.hostname)
    $principal_process_pid = array_distinct($reg.principal.process.pid)
    $principal_process_file_full_path = array_distinct($reg.principal.process.file.full_path)
    $principal_process_product_specific_process_id = array_distinct($reg.principal.process.product_specific_process_id)
    $principal_user_userid = array_distinct($reg.principal.user.userid)
    $target_registry_key = array_distinct($reg.target.registry.registry_key)
    $target_registry_value_data = array_distinct($reg.target.registry.registry_value_data)
    $log_type = array_distinct(strings.concat($reg.metadata.log_type,"/",$reg.metadata.product_event_type))

  condition:
    $reg
}